d6
/
modal
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity

Added tictactoe example

This commit is contained in:
Devine Lu Linvega 2024-04-11 17:01:48 -07:00
parent 2b7b68d713
commit e67d30d8f3
1 changed files with 44 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

44
examples/tictactoe.modal Normal file
View File

@ -0,0 +1,44 @@
-- (Tic Tac Toe)
<> (-- ?x) ()
<> (READ) (?~)
-- (Print)
<> (put-str ?:) (?:)
<> (put-row (?0 ?1 ?2)) (put-str ?0 put-str | put-str ?1 put-str | put-str ?2 put-str \n)
<> ((?a ?b ?c) display) (put-row ?a put-row ?b put-row ?c put-str \n (?a ?b ?c))
-- (Validation)
<> (((?x ?x ?x) ?0 ?1) ?x run) (?x victory)
<> ((?0 (?x ?x ?x) ?1) ?x run) (?x victory)
<> ((?0 ?1 (?x ?x ?x)) ?x run) (?x victory)
<> (((?x ?0 ?1) (?x ?2 ?3) (?x ?4 ?5)) ?x run) (?x victory)
<> (((?0 ?x ?1) (?2 ?x ?3) (?4 ?x ?5)) ?x run) (?x victory)
<> (((?0 ?1 ?x) (?2 ?3 ?x) (?4 ?5 ?x)) ?x run) (?x victory)
<> (((?x ?0 ?1) (?2 ?x ?3) (?4 ?5 ?x)) ?x run) (?x victory)
<> (((?0 ?1 ?x) (?2 ?1 ?3) (?x ?4 ?5)) ?x run) (?x victory)
-- (Game)
<> (((?0 ?1 ?2) ?a ?b) ?x 0 0 play) (((?x ?1 ?2) ?a ?b) display ?x run wait)
<> (((?0 ?1 ?2) ?a ?b) ?x 1 0 play) (((?0 ?x ?2) ?a ?b) display ?x run wait)
<> (((?0 ?1 ?2) ?a ?b) ?x 2 0 play) (((?0 ?1 ?x) ?a ?b) display ?x run wait)
<> ((?a (?0 ?1 ?2) ?b) ?x 0 1 play) ((?a (?x ?1 ?2) ?b) display ?x run wait)
<> ((?a (?0 ?1 ?2) ?b) ?x 1 1 play) ((?a (?0 ?x ?2) ?b) display ?x run wait)
<> ((?a (?0 ?1 ?2) ?b) ?x 2 1 play) ((?a (?0 ?1 ?x) ?b) display ?x run wait)
<> ((?a ?b (?0 ?1 ?2)) ?x 0 2 play) ((?a ?b (?x ?1 ?2)) display ?x run wait)
<> ((?a ?b (?0 ?1 ?2)) ?x 1 2 play) ((?a ?b (?0 ?x ?2)) display ?x run wait)
<> ((?a ?b (?0 ?1 ?2)) ?x 2 2 play) ((?a ?b (?0 ?1 ?x)) display ?x run wait)
-- (Play)
<> (ready) (display READ play)
<> (?x run wait) (READ play)
<> (?x victory) (put-str (?x wins!\n))
-- (Interface)
(put-str (Input a move, like "X 0 1":\n))
((- - -) (- - -) (- - -)) ready