419 lines
9.4 KiB
Tal
419 lines
9.4 KiB
Tal
( math32.tal )
|
|
( )
|
|
( 32-bit integers are represented by two 16-bit integers )
|
|
( x** means xhi* xlo* )
|
|
|
|
%DEBUG { #ff #0e DEO }
|
|
%RTN { JMP2r }
|
|
%EMIT { .Console/write DEO }
|
|
%DIGIT { #00 SWP ;digits ADD2 LDA EMIT }
|
|
%SPACE { #20 EMIT }
|
|
%NEWLINE { #0a EMIT }
|
|
|
|
%TOR { ROT ROT } ( a b c -> c a b )
|
|
%TOR2 { ROT2 ROT2 }
|
|
%POP4 { POP2 POP2 }
|
|
|
|
%X { #0000 #0001 }
|
|
%Y { #1234 #ffff }
|
|
%Z { #fedc #ba98 }
|
|
|
|
( devices )
|
|
|10 @Console [ &vector $2 &read $1 &pad $5 &write $1 ]
|
|
|
|
( program )
|
|
|0100
|
|
;interact .Console/vector DEO2
|
|
BRK
|
|
|
|
( e.g. #31 #33 -> #13 )
|
|
@parse-byte ( c0 c1 -> x^ )
|
|
( lower char )
|
|
DUP #3a LTH ,&lo-digit JCN
|
|
#57 ,&lo JMP &lo-digit #30
|
|
&lo SUB SWP
|
|
|
|
( higher char ))
|
|
DUP #3a LTH ,&hi-digit JCN
|
|
#57 ,&hi JMP &hi-digit #30
|
|
&hi SUB #40 SFT ORA
|
|
RTN
|
|
|
|
@buf $24
|
|
@pos $2
|
|
|
|
@read-byte ( addr* -> x^ )
|
|
LDA2 ;parse-byte JSR2
|
|
RTN
|
|
|
|
@read-long ( addr* -> x** )
|
|
DUP2 ,&loc STR2 LDA2 ;parse-byte JSR2
|
|
,&loc LDR2 #0002 ADD2 LDA2 ;parse-byte JSR2
|
|
,&loc LDR2 #0004 ADD2 LDA2 ;parse-byte JSR2
|
|
,&loc LDR2 #0006 ADD2 LDA2 ;parse-byte JSR2
|
|
RTN
|
|
[ &loc $2 ]
|
|
|
|
%POS++ { ;pos LDA2k INC2 SWP2 STA2 }
|
|
%RESET-POS { #0000 ;pos STA2 #00 ;buf STA }
|
|
|
|
@interact
|
|
.Console/read DEI ( char^ )
|
|
DUP #0a EQU ( char^ char=\n? )
|
|
,&exec JCN ( char^ )
|
|
;pos LDA2 ;buf ADD2 STA POS++ BRK
|
|
&exec
|
|
POP ( )
|
|
;buf LDA LIT '+ EQU ;test-add32 JCN2
|
|
;buf LDA LIT '* EQU ;test-mul32 JCN2
|
|
;buf LDA LIT '- EQU ;test-sub32 JCN2
|
|
;buf LDA LIT 'L EQU ;test-left-shift JCN2
|
|
;buf LDA LIT 'B EQU ;test-bitcount32 JCN2
|
|
;buf LDA LIT '& EQU ;test-and32 JCN2
|
|
;buf LDA LIT '| EQU ;test-or32 JCN2
|
|
;buf LDA LIT '^ EQU ;test-xor32 JCN2
|
|
;buf LDA LIT '~ EQU ;test-complement32 JCN2
|
|
;buf LDA LIT 'N EQU ;test-negate32 JCN2
|
|
;buf LDA LIT '= EQU ;test-eq32 JCN2
|
|
;buf LDA LIT '! EQU ;test-ne32 JCN2
|
|
LIT '? EMIT NEWLINE RESET-POS BRK
|
|
|
|
( format: ". xxxxxxxx" )
|
|
%UNARY-32-TEST {
|
|
;buf #0002 ADD2 ;read-long JSR2
|
|
ROT2 JSR2 ;emit-long JSR2
|
|
NEWLINE RESET-POS BRK
|
|
}
|
|
|
|
( format: ". xxxxxxxx yyyyyyyy" )
|
|
%BINARY-32-TEST {
|
|
;buf #0002 ADD2 ;read-long JSR2
|
|
ROT2
|
|
;buf #000b ADD2 ;read-long JSR2
|
|
ROT2 JSR2 ;emit-long JSR2
|
|
NEWLINE RESET-POS BRK
|
|
}
|
|
|
|
@test-add32 ;add32 BINARY-32-TEST
|
|
@test-mul32 ;mul32 BINARY-32-TEST
|
|
@test-sub32 ;sub32 BINARY-32-TEST
|
|
|
|
@test-left-shift
|
|
( format: "+ xxxxxxxx yy" )
|
|
;buf #0002 ADD2 ;read-long JSR2
|
|
;buf #000b ADD2 ;read-byte JSR2
|
|
;left-shift JSR2 ;emit-long JSR2
|
|
NEWLINE RESET-POS BRK
|
|
|
|
@test-bitcount32
|
|
( format: "B xxxxxxxx" )
|
|
;buf #0002 ADD2 ;read-long JSR2
|
|
;bitcount32 JSR2 ;emit-byte JSR2
|
|
NEWLINE RESET-POS BRK
|
|
|
|
@test-and32 ;and32 BINARY-32-TEST
|
|
@test-or32 ;or32 BINARY-32-TEST
|
|
@test-xor32 ;xor32 BINARY-32-TEST
|
|
@test-complement32 ;complement32 UNARY-32-TEST
|
|
@test-negate32 ;negate32 UNARY-32-TEST
|
|
|
|
@test-eq32
|
|
( format: "= xxxxxxxx yyyyyyyy" )
|
|
;buf #0002 ADD2 ;read-long JSR2
|
|
;buf #000b ADD2 ;read-long JSR2
|
|
;eq32 JSR2 ;emit-byte JSR2
|
|
NEWLINE RESET-POS BRK
|
|
|
|
@test-ne32
|
|
( format: "= xxxxxxxx yyyyyyyy" )
|
|
;buf #0002 ADD2 ;read-long JSR2
|
|
;buf #000b ADD2 ;read-long JSR2
|
|
;ne32 JSR2 ;emit-byte JSR2
|
|
NEWLINE RESET-POS BRK
|
|
|
|
@bitcount8 ( x^ -> n^ )
|
|
#00 SWP ( n x )
|
|
&loop
|
|
DUP #00 EQU ( n x x=0 )
|
|
,&done JCN ( n x )
|
|
#01 SFT ( n x>>1 )
|
|
SWP INC SWP ( n+1 x>>1 )
|
|
,&loop JMP
|
|
&done
|
|
POP ( n )
|
|
RTN
|
|
|
|
@bitcount16 ( x* -> n^ )
|
|
SWP ( xlo xhi )
|
|
;bitcount8 JSR2 ( xlo nhi )
|
|
DUP #00 NEQ ( xlo nhi nhi!=0 )
|
|
,&hi-set JCN ( xlo nhi )
|
|
SWP ;bitcount8 JSR2 ADD ( nhi+nlo )
|
|
RTN
|
|
&hi-set
|
|
SWP POP #08 ADD ( nhi+8 )
|
|
RTN
|
|
|
|
@bitcount32 ( x** -> n^ )
|
|
SWP2 ( xlo* xhi* )
|
|
;bitcount16 JSR2 ( xlo* nhi )
|
|
DUP #00 NEQ ( xlo* nhi nhi!=0 )
|
|
,&hi-set JCN ( xlo* nhi )
|
|
TOR ;bitcount16 JSR2 ADD RTN ( nhi+nlo )
|
|
&hi-set
|
|
TOR POP2 #10 ADD ( nhi+16 )
|
|
RTN
|
|
|
|
@eq32 ( xhi* xlo* yhi* ylo* -> bool^ )
|
|
ROT2 EQU2 #00 TOR2
|
|
EQU2 SWP POP AND
|
|
RTN
|
|
|
|
@eq-zero32 ( x** -> bool^ )
|
|
ORA2 #0000 EQU2
|
|
RTN
|
|
|
|
@ne32 ( xhi* xlo* yhi* ylo* -> bool^ )
|
|
ROT2 NEQ2 #00 TOR2
|
|
NEQ2 SWP POP ORA
|
|
RTN
|
|
|
|
@ne-zero32 ( x** -> bool^ )
|
|
ORA2 #0000 NEQ2
|
|
RTN
|
|
|
|
@and32 ( xhi* xlo* yhi* ylo* -> xhi|yhi* xlo|ylo* )
|
|
ROT2 AND2 TOR2 AND2 SWP2
|
|
RTN
|
|
|
|
@or32 ( xhi* xlo* yhi* ylo* -> xhi|yhi* xlo|ylo* )
|
|
ROT2 ORA2 TOR2 ORA2 SWP2
|
|
RTN
|
|
|
|
@xor32 ( xhi* xlo* yhi* ylo* -> xhi|yhi* xlo|ylo* )
|
|
ROT2 EOR2 TOR2 EOR2 SWP2
|
|
RTN
|
|
|
|
%COMPLEMENT32 { SWP2 #ffff EOR2 SWP2 #ffff EOR2 }
|
|
|
|
@complement32 ( x** -> ~x** )
|
|
COMPLEMENT32
|
|
RTN
|
|
|
|
@negate32 ( x** -> -x** )
|
|
COMPLEMENT32
|
|
INC2 ( ~xhi -xlo )
|
|
DUP2 #0000 NEQ2 ( ~xhi -xlo non-zero? )
|
|
,&done JCN ( xlo non-zero => don't inc hi )
|
|
SWP2 INC2 SWP2 ( -xhi -xlo )
|
|
&done
|
|
RTN
|
|
|
|
@left-by-16 ( xhi* xlo* -> xlo* 0000 )
|
|
SWP2 POP2 #0000
|
|
RTN
|
|
|
|
@left-shift ( x** n^ -> x<<n )
|
|
DUP #08 LTH ;left-shift0 JCN2 ( x n )
|
|
DUP #10 LTH ;left-shift1 JCN2 ( x n )
|
|
DUP #18 LTH ;left-shift2 JCN2 ( x n )
|
|
;left-shift3 JMP2 ( x n )
|
|
RTN
|
|
|
|
( shift left by 0-7 bits )
|
|
@left-shift0 ( x** n^ -> x<<n )
|
|
#0000 ,&z0 STR2 #0000 ,&z2 STR2
|
|
#40 SFT ,&r STR ( n<<4 -> r )
|
|
SWP SWP2 SWP ( x3 x2 x1 x0 )
|
|
|
|
,&r LDR SFT ,&z0 STR ( x3 x2 x1 )
|
|
|
|
#00 SWP ,&r LDR SFT2 ( x3 x2 00x1<<r )
|
|
,&z0 LDR2 ORA2 ,&z0 STR2 ( x3 x2 )
|
|
|
|
#00 SWP ,&r LDR SFT2 ( x3 00x2<<r )
|
|
,&z1 LDR2 ORA2 ,&z1 STR2 ( x3 )
|
|
|
|
#00 SWP ,&r LDR SFT2 ( 00x3<<r )
|
|
,&z2 LDR2 ORA2 ,&z2 STR2 ( )
|
|
|
|
,&z0 LDR2 ,&z2 LDR2
|
|
RTN
|
|
[ &r $1 &z0 $1 &z1 $1 &z2 $1 &z3 $1 ]
|
|
|
|
( shift left by 8-15 bits )
|
|
@left-shift1 ( x** n^ -> x<<n )
|
|
#0000 ,&z0 STR2 #00 ,&z2 STR
|
|
#08 SUB #40 SFT ,&r STR ( n<<4 -> r )
|
|
SWP SWP2 SWP POP ( x3 x2 x1 )
|
|
|
|
,&r LDR SFT ,&z0 STR ( x3 x2 )
|
|
|
|
#00 SWP ,&r LDR SFT2 ( x3 00x2<<r )
|
|
,&z0 LDR2 ORA2 ,&z0 STR2 ( x3 )
|
|
|
|
#00 SWP ,&r LDR SFT2 ( 00x3<<r )
|
|
,&z1 LDR2 ORA2 ,&z1 STR2 ( )
|
|
|
|
,&z0 LDR2 ,&z2 LDR #00
|
|
RTN
|
|
[ &r $1 &z0 $1 &z1 $1 &z2 $1 ]
|
|
|
|
( shift left by 16-23 bits )
|
|
@left-shift2 ( x** n^ -> x<<n )
|
|
#0000 ,&z0 STR2
|
|
#10 SUB #40 SFT ,&r STR ( n<<4 -> r )
|
|
SWP2 POP2 SWP ( x3 x2 )
|
|
|
|
,&r LDR SFT ,&z0 STR ( x3 )
|
|
|
|
#00 SWP ,&r LDR SFT2 ( x3<<r )
|
|
,&z0 LDR2 ORA2 ,&z0 STR2 ( )
|
|
|
|
,&z0 LDR2 #0000
|
|
RTN
|
|
[ &r $1 &z0 $1 &z1 $1 ]
|
|
|
|
( shift left by 24-31 bits )
|
|
@left-shift3 ( x** n^ -> x<<n )
|
|
#18 SUB #10 MUL ( x0 x1 x2 x3 r=[n-24]<<4 )
|
|
SFT ( x0 x1 x2 x3<<r )
|
|
SWP2 POP2 SWP POP #0000 #00
|
|
RTN
|
|
|
|
@add32 ( xhi* xlo* yhi* ylo* -> zhi* zlo* )
|
|
,&y2 STR2 ,&y0 STR2 ( save ylo, yhi )
|
|
,&x2 STR2 ,&x0 STR2 ( save xlo, xhi )
|
|
#0000 #0000 ,&z0 STR2 ,&z2 STR2 ( reset zhi, zlo )
|
|
|
|
( x3 + y3 => z2z3 )
|
|
#00 ,&x3 LDR #00 ,&y3 LDR ADD2 ,&z2 STR2
|
|
|
|
( x2 + y2 + z2 => z1z2 )
|
|
#00 ,&x2 LDR ,&z1 LDR2 ADD2 ,&z1 STR2
|
|
#00 ,&y2 LDR ,&z1 LDR2 ADD2 ,&z1 STR2
|
|
|
|
( x1 + y1 + z1 => z0z1 )
|
|
#00 ,&x1 LDR ,&z0 LDR2 ADD2 ,&z0 STR2
|
|
#00 ,&y1 LDR ,&z0 LDR2 ADD2 ,&z0 STR2
|
|
|
|
( x0 + y0 + z0 => z0 )
|
|
,&x0 LDR ,&z0 LDR ADD ,&z0 STR
|
|
,&y0 LDR ,&z0 LDR ADD ,&z0 STR
|
|
|
|
( load zhi,zlo )
|
|
,&z0 LDR2 ,&z2 LDR2
|
|
RTN
|
|
( registers for add32 )
|
|
[ &x0 $1 &x1 $1 &x2 $1 &x3 $1 ]
|
|
[ &y0 $1 &y1 $1 &y2 $1 &y3 $1 ]
|
|
[ &z0 $1 &z1 $1 &z2 $2 ]
|
|
|
|
@sub32 ( x** y** -> z** )
|
|
;negate32 JSR2 ;add32 JSR2
|
|
RTN
|
|
|
|
@mul16 ( x* y* -> z** )
|
|
,&y1 STR ,&y0 STR ( save ylo, yhi )
|
|
,&x1 STR ,&x0 STR ( save xlo, xhi )
|
|
#0000 #00 ,&z0 STR2 ,&z2 STR ( reset z0,z1,z2 )
|
|
#0000 #00 ,&a0 STR2 ,&a2 STR ( reset a0,a1,a2 )
|
|
|
|
( x1 * y1 => z1z2 )
|
|
#00 ,&x1 LDR #00 ,&y1 LDR MUL2 ,&z1 STR2
|
|
|
|
( x0 * y1 => z0z1 )
|
|
#00 ,&x0 LDR #00 ,&y1 LDR MUL2 ,&z0 LDR2 ADD2 ,&z0 STR2
|
|
|
|
( x1 * y0 => a1a2 )
|
|
#00 ,&x1 LDR #00 ,&y0 LDR MUL2 ,&a1 STR2
|
|
|
|
( x0 * y0 => a0a1 )
|
|
#00 ,&x0 LDR #00 ,&y0 LDR MUL2 ,&a0 LDR2 ADD2 ,&a0 STR2
|
|
|
|
( add z and a<<8 )
|
|
#00 ,&z0 LDR2 ,&z2 LDR
|
|
,&a0 LDR2 ,&a2 LDR #00
|
|
;add32 JSR2
|
|
RTN
|
|
[ &x0 $1 &x1 $1 ]
|
|
[ &y0 $1 &y1 $1 ]
|
|
[ &z0 $1 &z1 $1 &z2 $1 ]
|
|
[ &a0 $1 &a1 $1 &a2 $1 ]
|
|
|
|
@mul32 ( x** y** -> z** )
|
|
,&y1 STR2 ,&y0 STR2 ( save ylo, yhi )
|
|
,&x1 STR2 ,&x0 STR2 ( save xlo, xhi )
|
|
,&y1 LDR2 ,&x1 LDR2 ;mul16 JSR2 ( [x1*y1] )
|
|
,&z1 STR2 ,&z0 STR2 ( sum = x1*y1, save zlo, zhi )
|
|
|
|
,&y1 LDR2 ,&x0 LDR2 MUL2 ( [x0*y1]<<16 )
|
|
,&y0 LDR2 ,&x1 LDR2 MUL2 ( [x1*y0]<<16 )
|
|
( [x0*y0]<<32 will completely overflow )
|
|
ADD2 ,&z0 LDR2 ADD2 ( sum += x0*y1<<16 + x1*y0<<16 )
|
|
,&z1 LDR2
|
|
RTN
|
|
[ &x0 $2 &x1 $2 ]
|
|
[ &y0 $2 &y1 $2 ]
|
|
[ &z0 $2 &z1 $2 ]
|
|
|
|
@divmod32-by-32 ( x** y** -> q** r** )
|
|
,&div1 STR2 ,&div0 STR2 ( y -> div )
|
|
,&rem1 STR2 ,&rem0 STR2 ( x -> rem )
|
|
#0000 #0000 ,&quo1 STR2 ,&quo0 ( 0 -> quo )
|
|
,&rem0 LDR2 ,&rem1 LDR2 ;bitcount32 JSR2 ( rembits^ )
|
|
,&div1 LDR2 ,&div0 LDR2 ;bitcount32 JSR2 ( rembits^ divbits^ )
|
|
SUBk ,&shift STR ( rembits divbits )
|
|
,&div0 LDR2 ,&div1 LDR2
|
|
|
|
|
|
RTN
|
|
[ &div0 $2 &div1 $2
|
|
&rem0 $2 &rem1 $2
|
|
&quo0 $2 &quo1 $2
|
|
&shift $1 ]
|
|
|
|
@divmod16-by-8 ( x* y^ -> q* r^ )
|
|
DUP ,&y STR
|
|
ROT SWP ( x1 x0 y )
|
|
DIVk ( x1 x0 y q0 )
|
|
DUP ,&q0 STR ( x1 x0 y q0 )
|
|
MUL SUB ( x1 r=x0-y*q0 )
|
|
SWP #00 ,&y LDR ( r x1 00 y )
|
|
DIV2k ( rx1 00y q1 )
|
|
DUP2 ROT2 MUL2 ( rx1 q1 y*q1 )
|
|
ROT2 SWP2 SUB2 ( q1 rr=rx1-y*q1 )
|
|
SWP POP ( q1 rrlo )
|
|
ROT POP ( q1lo rrlo )
|
|
,&q0 LDR TOR
|
|
RTN
|
|
[ &y $1 &q0 $1 ]
|
|
|
|
@emit-long ( hi* lo* -> )
|
|
SWP2 ( lo* hi* )
|
|
;emit-short JSR2
|
|
;emit-short JSR2
|
|
RTN
|
|
|
|
%EMIT-BYTE { DUP #04 SFT DIGIT #0f AND DIGIT }
|
|
|
|
@emit-short-byte ( x* y^ - > )
|
|
TOR ( y^ x* )
|
|
;emit-short JSR2
|
|
SPACE
|
|
;emit-byte JSR2
|
|
RTN
|
|
|
|
@emit-short ( x* -> )
|
|
SWP ( lo^ hi^ )
|
|
EMIT-BYTE EMIT-BYTE
|
|
RTN
|
|
|
|
@emit-byte ( x^ -> )
|
|
EMIT-BYTE
|
|
RTN
|
|
|
|
@digits
|
|
30 31 32 33 34 35 36 37
|
|
38 39 61 62 63 64 65 66
|