uxn-utils/gui/shaviankb/shaviankb.tal

( uxnemu shaviankb.rom | listener )

|00 @System &vector $2 &expansion $2 &wst $1 &rst $1 &metadata $2 &r $2 &g $2 &b $2 &debug $1 &state $1
|10 @Console &vector $2 &read $1 &pad $4 &type $1 &write $1 &error $1
|20 @Screen &vector $2 &width $2 &height $2 &auto $1 &pad $1 &x $2 &y $2 &addr $2 &pixel $1 &sprite $1

|0000

|0100

@on-reset ( -> )
	#f0ef .System/r DEO2
	#f0e6 .System/g DEO2
	#f0e2 .System/b DEO2
	#0120 .Screen/width DEO2
	#00c0 .Screen/height DEO2
	<draw-keyboard>
	( #010e DEO ) BRK

@<set-position> ( id* -- )
	DUP2 #0009 DIV2 #0030 MUL2 .Screen/y DEO2
	DUP #1e NEQ ?{ POP2 #0007 }
	DUP #1f NEQ ?{ POP2 #0008 }
	#0009 DIV2k MUL2 SUB2 #0020 MUL2 .Screen/x DEO2
	JMP2r

@<draw-keyboard> ( -- )
	#0020 #0000
	&l ( -- )
		DUP2 <set-position>
		DUP2 #0006 MUL2 ;layout ADD2
		( ) STH2k #0004 ADD2 LDA2
		( ) STH2kr #0002 ADD2 LDA2
		( ) STH2r LDA2 <draw-key>
		( ) INC2 GTH2k ?&l
	POP2 POP2 JMP2r

@<draw-glyph> ( addr* -- )
	.Screen/addr DEO2
	[ LIT2 15 -Screen/auto ] DEO
	[ LIT2 05 -Screen/sprite ] DEO
	JMP2r

@<draw-key> ( a* b* c* -- )
	<draw-button>
	.Screen/x DEI2k #0006 ADD2 ROT DEO2
	.Screen/y DEI2k #0004 ADD2 ROT DEO2
	( | a )
	<draw-glyph>
	.Screen/x DEI2k #0002 SUB2 ROT DEO2
	.Screen/y DEI2k #000c ADD2 ROT DEO2
	( | b )
	<draw-glyph>
	.Screen/x DEI2k #0002 SUB2 ROT DEO2
	.Screen/y DEI2k #000c ADD2 ROT DEO2
	( | c )
	<draw-glyph>
	.Screen/x DEI2k #0006 ADD2 ROT DEO2
	.Screen/y DEI2k #001c SUB2 ROT DEO2
	JMP2r

@<draw-button> ( -- )
	.Screen/x DEI2 .Screen/y DEI2
	( | draw )
	[ LIT2 36 -Screen/auto ] DEO
	;button-icn/top .Screen/addr DEO2
	[ LIT2 01 -Screen/sprite ] DEOk DEOk
	( ) ;button-icn/middle .Screen/addr DEO2
	DEOk
	( ) ;button-icn/middle .Screen/addr DEO2
	DEOk
	( ) ;button-icn/middle .Screen/addr DEO2
	DEOk DEO
	.Screen/y DEO2
	.Screen/x DEO2
	JMP2r

(
@|stdlib )

@<phex> ( short* -- )
	SWP <phex>/b
	&b ( -- )
		DUP #04 SFT <phex>/c
	&c ( -- )
		#0f AND DUP #09 GTH #27 MUL ADD [ LIT "0 ] ADD #18 DEO
		JMP2r

~assets.tal