( uxncli hx.rom file.bin )

|10 @Console &vector $2 &read $1 &pad $4 &type $1 &write $1 &error $1
|a0 @File &vector $2 &success $2 &stat $2 &delete $1 &append $1 &name $2 &length $2 &read $2 &write $2

|0000

	@src $40

|0100

@on-reset ( -> )
	.Console/type DEI ?{
		;Dict/usage <perr>/
		#010f DEO
		BRK }
	;await-src .Console/vector DEO2
	BRK

@await-src ( -> )
	.Console/read DEI .src skey ?on-ready
	BRK

@on-ready ( -> )
	;src .File/name DEO2
	#0001 .File/length DEO2
	#0a19 DEO
	#0000
	&stream ( -- )
		;&b .File/read DEO2
		.File/success DEI2 #0000 EQU2 ?&eof
		[ LIT &b $1 ] <phex>/b
		INC2 DUP <print-spacer>
		!&stream
	&eof ( id -- )
		#0a19 DEOk DEO
		<pdec>
		;Dict/bytes <perr>
		;src <perr>
		#0a19 DEO
		#800f DEO
		BRK

@<print-spacer> ( id -- )
	DUP #0f AND ?{
		POP #0a18 DEO
		JMP2r }
	#01 AND ?{ #2018 DEO }
	JMP2r

(
@|stdlib )

@skey ( key buf -- proc )
	OVR #21 LTH ?{
		#00 SWP sput #00 JMP2r }
	POP2 #01 JMP2r

@scap ( str* -- end* )
	&w ( -- )
		INC2 & LDAk ?&w
	JMP2r

@sput ( chr str* -- )
	scap/ ROT #00 SWP2 STA2
	JMP2r

@<phex> ( short* -- )
	SWP <phex>/b
	&b ( -- )
		DUP #04 SFT <phex>/c
	&c ( -- )
		#0f AND DUP #09 GTH #27 MUL ADD LIT "0 ADD #18 DEO
		JMP2r

@<perr> ( err* -- )
	&w ( -- )
		LDAk #19 DEO
		INC2 & LDAk ?&w
	POP2 JMP2r

@<pdec> ( short* -- )
	#2710 [ LIT2r 00fb ]
	&w ( -- )
		DIV2k #000a DIV2k MUL2 SUB2 SWPr EQUk OVR STHkr EQU AND ?{
			DUP [ LIT "0 ] ADD #19 DEO
			INCr }
		POP2 #000a DIV2 SWPr INCr STHkr ?&w
	POP2r POP2 POP2 JMP2r

(
@|res )

@Dict &usage "usage: 20 "hx.rom 20 "input.bin 0a $1
	&bytes 20 "bytes 20 "in 20 $1