105 lines
3.1 KiB
Plaintext
105 lines
3.1 KiB
Plaintext
( GUI Hover )
|
|
|
|
%RTN { JMP2r }
|
|
|
|
( devices )
|
|
|
|
|00 @System [ &vector $2 &pad $6 &r $2 &g $2 &b $2 ]
|
|
|20 @Screen [ &vector $2 &width $2 &height $2 &pad $2 &x $2 &y $2 &addr $2 &color $1 ]
|
|
|90 @Mouse [ &vector $2 &x $2 &y $2 &state $1 &chord $1 ]
|
|
|
|
( variables )
|
|
|
|
|0000
|
|
|
|
@color [ &byte $1 ]
|
|
@pointer [ &x $2 &y $2 &sprite $2 ]
|
|
@rect [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
@r1 [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
@r2 [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
@r3 [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
|
|
( program )
|
|
|
|
|0100
|
|
|
|
( theme ) #0f0f .System/r DEO2 #0fff .System/g DEO2 #0ff0 .System/b DEO2
|
|
( vectors ) ;on-mouse .Mouse/vector DEO2
|
|
|
|
#0020 #0030 #0060 #0060 .r1/y2 STZ2 .r1/x2 STZ2 .r1/y1 STZ2 .r1/x1 STZ2
|
|
#0058 #0050 #0090 #0080 .r2/y2 STZ2 .r2/x2 STZ2 .r2/y1 STZ2 .r2/x1 STZ2
|
|
#0048 #0048 #0080 #0098 .r3/y2 STZ2 .r3/x2 STZ2 .r3/y1 STZ2 .r3/x1 STZ2
|
|
|
|
( no BRK, run through to on-mouse )
|
|
|
|
@on-mouse
|
|
|
|
;pointer_icn .pointer/sprite STZ2
|
|
|
|
#01 .color STZ
|
|
( matrix comparison )
|
|
.Mouse/x DEI2 .r1/x1 LDZ2 GTH2 .Mouse/x DEI2 .r1/x2 LDZ2 LTH2 #0101 EQU2
|
|
.Mouse/y DEI2 .r1/y1 LDZ2 GTH2 .Mouse/y DEI2 .r1/y2 LDZ2 LTH2 #0101 EQU2
|
|
#0101 NEQ2 ,&draw1 JCN #02 .color STZ ;hand_icn .pointer/sprite STZ2
|
|
&draw1 .r1/x1 LDZ2 .r1/y1 LDZ2 .r1/x2 LDZ2 .r1/y2 LDZ2 .color LDZ ;line-rect JSR2
|
|
|
|
#01 .color STZ
|
|
( 2-step comparison )
|
|
.Mouse/x DEI2 .r2/x1 LDZ2 GTH2 .Mouse/x DEI2 .r2/x2 LDZ2 LTH2 #0101 NEQ2 ,&draw2 JCN
|
|
.Mouse/y DEI2 .r2/y1 LDZ2 GTH2 .Mouse/y DEI2 .r2/y2 LDZ2 LTH2 #0101 NEQ2 ,&draw2 JCN
|
|
#03 .color STZ ;hand_icn .pointer/sprite STZ2
|
|
&draw2 .r2/x1 LDZ2 .r2/y1 LDZ2 .r2/x2 LDZ2 .r2/y2 LDZ2 .color LDZ ;line-rect JSR2
|
|
|
|
#01 .color STZ
|
|
( 4-step comparison )
|
|
.Mouse/x DEI2 .r3/x1 LDZ2 LTH2 ,&draw3 JCN
|
|
.Mouse/x DEI2 .r3/x2 LDZ2 GTH2 ,&draw3 JCN
|
|
.Mouse/y DEI2 .r3/y1 LDZ2 LTH2 ,&draw3 JCN
|
|
.Mouse/y DEI2 .r3/y2 LDZ2 GTH2 ,&draw3 JCN
|
|
#02 .color STZ ;hand_icn .pointer/sprite STZ2
|
|
&draw3 .r3/x1 LDZ2 .r3/y1 LDZ2 .r3/x2 LDZ2 .r3/y2 LDZ2 .color LDZ ;line-rect JSR2
|
|
|
|
;draw-cursor JSR2
|
|
|
|
BRK
|
|
|
|
@draw-cursor
|
|
|
|
( clear last cursor )
|
|
;clear_icn .Screen/addr DEO2
|
|
.pointer/x LDZ2 .Screen/x DEO2
|
|
.pointer/y LDZ2 .Screen/y DEO2
|
|
#30 .Screen/color DEO
|
|
|
|
( record pointer positions )
|
|
.Mouse/x DEI2 .pointer/x STZ2 .Mouse/y DEI2 .pointer/y STZ2
|
|
|
|
( draw new cursor )
|
|
.pointer/sprite LDZ2 .Screen/addr DEO2
|
|
.pointer/x LDZ2 .Screen/x DEO2
|
|
.pointer/y LDZ2 .Screen/y DEO2
|
|
#31 .Screen/color DEO
|
|
|
|
RTN
|
|
|
|
@line-rect ( x1* y1* x2* y2* color -- )
|
|
|
|
( load ) .color STZ .rect/y2 STZ2 .rect/x2 STZ2 DUP2 .Screen/y DEO2 .rect/y1 STZ2 DUP2 .Screen/x DEO2 .rect/x1 STZ2
|
|
&hor
|
|
( incr ) .Screen/x DEI2 #0001 ADD2 .Screen/x DEO2
|
|
( draw ) .rect/y1 LDZ2 .Screen/y DEO2 .color LDZ .Screen/color DEO
|
|
( draw ) .rect/y2 LDZ2 .Screen/y DEO2 .color LDZ .Screen/color DEO
|
|
.Screen/x DEI2 .rect/x2 LDZ2 LTH2 ,&hor JCN
|
|
.rect/y1 LDZ2 .Screen/y DEO2
|
|
&ver
|
|
( draw ) .rect/x1 LDZ2 .Screen/x DEO2 .color LDZ .Screen/color DEO
|
|
( draw ) .rect/x2 LDZ2 .Screen/x DEO2 .color LDZ .Screen/color DEO
|
|
( incr ) .Screen/y DEI2 #0001 ADD2 .Screen/y DEO2
|
|
.Screen/y DEI2 .rect/y2 LDZ2 #0001 ADD2 LTH2 ,&ver JCN
|
|
|
|
RTN
|
|
|
|
@clear_icn [ 0000 0000 0000 0000 ]
|
|
@pointer_icn [ 80c0 e0f0 f8e0 1000 ]
|
|
@hand_icn [ 4040 4070 f8f8 f870 ]
|