nxu/math32.tal

( math32.tal )
( )
( 32-bit integers are represented by two 16-bit integers )
( x** means xhi* xlo* )

%DEBUG { #ff #0e DEO }
%RTN  { JMP2r }
%TOR { ROT ROT } ( a b c -> c a b )
%TOR2 { ROT2 ROT2 }
%POP4 { POP2 POP2 }
%COMPLEMENT32 { SWP2 #ffff EOR2 SWP2 #ffff EOR2 } )

( bitcount: number of bits needed to represent number )
( equivalent to floor[log2[x]] + 1 )

@bitcount8 ( x^ -> n^ )
    #00 SWP ( n x )
    &loop
    DUP #00 EQU ( n x x=0 )
    ,&done JCN ( n x )
    #01 SFT ( n x>>1 )
    SWP INC SWP ( n+1 x>>1 )
    ,&loop JMP
    &done
    POP ( n )
    RTN

@bitcount16 ( x* -> n^ )
    SWP ( xlo xhi )
    ;bitcount8 JSR2 ( xlo nhi )
    DUP #00 NEQ ( xlo nhi nhi!=0 )
    ,&hi-set JCN ( xlo nhi )
    SWP ;bitcount8 JSR2 ADD ( nhi+nlo )
    RTN 
    &hi-set
    SWP POP #08 ADD ( nhi+8 )
    RTN

@bitcount32 ( x** -> n^ )
    SWP2 ( xlo* xhi* )
    ;bitcount16 JSR2 ( xlo* nhi )
    DUP #00 NEQ ( xlo* nhi nhi!=0 )
    ,&hi-set JCN ( xlo* nhi )
    TOR ;bitcount16 JSR2 ADD RTN ( nhi+nlo )
    &hi-set
    TOR POP2 #10 ADD ( nhi+16 )    
    RTN

( equality )

@eq32 ( xhi* xlo* yhi* ylo* -> bool^ )
    ROT2 EQU2 #00 TOR2
    EQU2 SWP POP AND RTN

@is-zero32 ( x** -> bool^ )
    ORA2 #0000 EQU2 RTN

@ne32 ( xhi* xlo* yhi* ylo* -> bool^ )
    ROT2 NEQ2 #00 TOR2
    NEQ2 SWP POP ORA RTN

@non-zero32 ( x** -> bool^ )
    ORA2 #0000 NEQ2 RTN

( comparisons )

( x < y )
@lt32 ( x** y** -> bool^ )
    ROT2 SWP2 ( xhi yhi xlo ylo )
    LTH2 ,&lt-lo JCN ( xhi yhi )
    LTH2 RTN
    &lt-lo
    GTH2 #00 EQU RTN

( x <= y )
@lteq32 ( x** y** -> bool^ )
    ROT2 SWP2 ( xhi yhi xlo ylo )
    GTH2 ,&gt-lo JCN ( xhi yhi )
    GTH2 #00 EQU RTN
    &gt-lo
    LTH2 RTN

( x > y )
@gt32 ( x** y** -> bool^ )
    ROT2 SWP2 ( xhi yhi xlo ylo )
    GTH2 ,&gt-lo JCN ( xhi yhi )
    GTH2 RTN
    &gt-lo
    LTH2 #00 EQU RTN

( x > y )
@gteq32 ( x** y** -> bool^ )
    ROT2 SWP2 ( xhi yhi xlo ylo )
    LTH2 ,&lt-lo JCN ( xhi yhi )
    LTH2 #00 EQU RTN
    &lt-lo
    GTH2 RTN

( bitwise operations )

@and32 ( xhi* xlo* yhi* ylo* -> xhi|yhi* xlo|ylo* )
    ROT2 AND2 TOR2 AND2 SWP2 RTN

@or32 ( xhi* xlo* yhi* ylo* -> xhi|yhi* xlo|ylo* )
    ROT2 ORA2 TOR2 ORA2 SWP2 RTN

@xor32 ( xhi* xlo* yhi* ylo* -> xhi|yhi* xlo|ylo* )
    ROT2 EOR2 TOR2 EOR2 SWP2 RTN

@complement32 ( x** -> ~x** )
    COMPLEMENT32 RTN

( temporary registers )
( used by all operations except div32 )
@sh [
  &r $1
  &x0 $1 &x1 $1 &x2 $1 &x3 $1
  &y0 $1 &y1 $1 &y2 $1 &y3 $1
  &z0 $1 &z1 $1 &z2 $1 &z3 $1
  &a0 $1 &a1 $1 &a2 $2
]

( bit shifting )

@right-shift ( x** n^ -> x<<n )
    DUP #08 LTH ;right-shift0 JCN2 ( x n )
    DUP #10 LTH ;right-shift1 JCN2 ( x n )
    DUP #18 LTH ;right-shift2 JCN2 ( x n )
    ;right-shift3 JMP2 ( x n )    
    RTN

( shift right by 0-7 bits )
@right-shift0 ( x** n^ -> x<<n )
    #0000 ;sh/z0 STA2 #0000 ;sh/z2 STA2
    ;sh/r STA ( n -> r )
    ;sh/r LDA SFT ;sh/z3 STA ( write z3 )
    #00 ;sh/r LDA SFT2 ;sh/z2 LDA2 ORA2 ;sh/z2 STA2 ( write z2,z3 )
    #00 ;sh/r LDA SFT2 ;sh/z1 LDA2 ORA2 ;sh/z1 STA2 ( write z1,z2 )
    #00 ;sh/r LDA SFT2 ;sh/z0 LDA2 ORA2 ;sh/z0 STA2 ( write z0,z1 )
    ;sh/z0 LDA2 ;sh/z2 LDA2
    RTN

( shift right by 8-15 bits )
@right-shift1 ( x** n^ -> x<<n )
    #00 ;sh/z1 STA #0000 ;sh/z2 STA2
    #08 SUB ;sh/r STA ( n -> r )
    POP
    ;sh/r LDA SFT ;sh/z3 STA ( write z3 )
    #00 ;sh/r LDA SFT2 ;sh/z2 LDA2 ORA2 ;sh/z2 STA2 ( write z2,z3 )
    #00 ;sh/r LDA SFT2 ;sh/z1 LDA2 ORA2 ;sh/z1 STA2 ( write z1,z2 )
    #00 ;sh/z1 LDA ;sh/z2 LDA2
    RTN

( shift right by 16-23 bits )
@right-shift2 ( x** n^ -> x<<n )
    #0000 ;sh/z2 STA2
    #10 SUB ;sh/r STA ( n -> r )
    POP2
    ;sh/r LDA SFT ;sh/z3 STA ( write z3 )
    #00 ;sh/r LDA SFT2 ;sh/z2 LDA2 ORA2 ;sh/z2 STA2 ( write z2,z3 )
    #0000 ;sh/z2 LDA2
    RTN

( shift right by 16-23 bits )
@right-shift3 ( x** n^ -> x<<n )
    #18 SUB ;sh/r STA ( n -> r )
    POP2 POP #00 SWP #0000 SWP2 ( 00 00 00 x0 )
    ;sh/r LDA SFT
    RTN

@left-shift ( x** n^ -> x<<n )
    DUP #08 LTH ;left-shift0 JCN2 ( x n )
    DUP #10 LTH ;left-shift1 JCN2 ( x n )
    DUP #18 LTH ;left-shift2 JCN2 ( x n )
    ;left-shift3 JMP2 ( x n )    
    RTN

( shift left by 0-7 bits )
@left-shift0 ( x** n^ -> x<<n )
    #0000 ;sh/z0 STA2 #0000 ;sh/z2 STA2
    #40 SFT ;sh/r STA ( n<<4 -> r )
    SWP SWP2 SWP ( x3 x2 x1 x0 )

    ;sh/r LDA SFT ;sh/z0 STA ( x3 x2 x1 )

    #00 SWP ;sh/r LDA SFT2 ( x3 x2 00x1<<r )
    ;sh/z0 LDA2 ORA2 ;sh/z0 STA2 ( x3 x2 )

    #00 SWP ;sh/r LDA SFT2 ( x3 00x2<<r )
    ;sh/z1 LDA2 ORA2 ;sh/z1 STA2 ( x3 )

    #00 SWP ;sh/r LDA SFT2 ( 00x3<<r )
    ;sh/z2 LDA2 ORA2 ;sh/z2 STA2 ( )

    ;sh/z0 LDA2 ;sh/z2 LDA2
    RTN

( shift left by 8-15 bits )
@left-shift1 ( x** n^ -> x<<n )
    #0000 ;sh/z0 STA2 #00 ;sh/z2 STA
    #08 SUB #40 SFT ;sh/r STA ( n<<4 -> r )
    SWP SWP2 SWP POP ( x3 x2 x1 )

    ;sh/r LDA SFT ;sh/z0 STA ( x3 x2 )

    #00 SWP ;sh/r LDA SFT2 ( x3 00x2<<r )
    ;sh/z0 LDA2 ORA2 ;sh/z0 STA2 ( x3 )

    #00 SWP ;sh/r LDA SFT2 ( 00x3<<r )
    ;sh/z1 LDA2 ORA2 ;sh/z1 STA2 ( )

    ;sh/z0 LDA2 ;sh/z2 LDA #00
    RTN

( shift left by 16-23 bits )
@left-shift2 ( x** n^ -> x<<n )
    #0000 ;sh/z0 STA2
    #10 SUB #40 SFT ;sh/r STA ( n<<4 -> r )
    SWP2 POP2 SWP ( x3 x2 )

    ;sh/r LDA SFT ;sh/z0 STA ( x3 )

    #00 SWP ;sh/r LDA SFT2 ( x3<<r )
    ;sh/z0 LDA2 ORA2 ;sh/z0 STA2 (  )

    ;sh/z0 LDA2 #0000
    RTN

( shift left by 24-31 bits )
@left-shift3 ( x** n^ -> x<<n )
    #18 SUB #10 MUL ( x0 x1 x2 x3 r=[n-24]<<4 )
    SFT ( x0 x1 x2 x3<<r )
    SWP2 POP2 SWP POP #0000 #00
    RTN

( arithmetic )

@add32 ( xhi* xlo* yhi* ylo* -> zhi* zlo* )
    ;sh/y2 STA2 ;sh/y0 STA2 ( save ylo, yhi )
    ;sh/x2 STA2 ;sh/x0 STA2 ( save xlo, xhi )
    #0000 #0000 ;sh/z0 STA2 ;sh/z2 STA2 ( reset zhi, zlo )

    ( x3 + y3 => z2z3 )
    #00 ;sh/x3 LDA #00 ;sh/y3 LDA ADD2 ;sh/z2 STA2

    ( x2 + y2 + z2 => z1z2 )
    #00 ;sh/x2 LDA ;sh/z1 LDA2 ADD2 ;sh/z1 STA2
    #00 ;sh/y2 LDA ;sh/z1 LDA2 ADD2 ;sh/z1 STA2

    ( x1 + y1 + z1 => z0z1 )
    #00 ;sh/x1 LDA ;sh/z0 LDA2 ADD2 ;sh/z0 STA2
    #00 ;sh/y1 LDA ;sh/z0 LDA2 ADD2 ;sh/z0 STA2

    ( x0 + y0 + z0 => z0 )
    ;sh/x0 LDA ;sh/z0 LDA ADD ;sh/z0 STA
    ;sh/y0 LDA ;sh/z0 LDA ADD ;sh/z0 STA

    ( load zhi,zlo )
    ;sh/z0 LDA2 ;sh/z2 LDA2
    RTN

@negate32 ( x** -> -x** )
    COMPLEMENT32
    INC2 ( ~xhi -xlo )
    DUP2 #0000 NEQ2 ( ~xhi -xlo non-zero? )
    ,&done JCN ( xlo non-zero => don't inc hi )
    SWP2 INC2 SWP2 ( -xhi -xlo )
    &done
    RTN

@sub32 ( x** y** -> z** )
    ;negate32 JSR2 ;add32 JSR2 RTN

@mul16 ( x* y* -> z** )
    ;sh/y1 STA ;sh/y0 STA ( save ylo, yhi )
    ;sh/x1 STA ;sh/x0 STA ( save xlo, xhi )
    #0000 #00 ;sh/z1 STA2 ;sh/z3 STA ( reset z1,z2,z3 )
    #0000 #00 ;sh/a0 STA2 ;sh/a2 STA ( reset a0,a1,a2 )

    ( x1 * y1 => z1z2 )
    #00 ;sh/x1 LDA #00 ;sh/y1 LDA MUL2 ;sh/z2 STA2

    ( x0 * y1 => z0z1 )
    #00 ;sh/x0 LDA #00 ;sh/y1 LDA MUL2 ;sh/z1 LDA2 ADD2 ;sh/z1 STA2

    ( x1 * y0 => a1a2 )
    #00 ;sh/x1 LDA #00 ;sh/y0 LDA MUL2 ;sh/a1 STA2

    ( x0 * y0 => a0a1 )
    #00 ;sh/x0 LDA #00 ;sh/y0 LDA MUL2 ;sh/a0 LDA2 ADD2 ;sh/a0 STA2

    ( add z and a<<8 )
    #00 ;sh/z1 LDA2 ;sh/z3 LDA
    ;sh/a0 LDA2 ;sh/a2 LDA #00
    ;add32 JSR2
    RTN

@mul32 ( x** y** -> z** )
    ,&y2 STR2 ,&y0 STR2 ( save ylo, yhi )
    ,&x2 STR2 ,&x0 STR2 ( save xlo, xhi )
    ,&y2 LDR2 ,&x2 LDR2 ;mul16 JSR2 ( [x2*y2] )
    ,&z2 STR2 ,&z0 STR2 ( sum = x2*y2, save zlo, zhi )

    ,&y2 LDR2 ,&x0 LDR2 MUL2 ( [x0*y2]<<16 )
    ,&y0 LDR2 ,&x2 LDR2 MUL2 ( [x2*y0]<<16 )
    ( [x0*y0]<<32 will completely overflow )
    ADD2 ,&z0 LDR2 ADD2 ( sum += x0*y2<<16 + x2*y0<<16 )
    ,&z2 LDR2
    RTN
[ &x0 $2 &x2 $2 ]
[ &y0 $2 &y2 $2 ]
[ &z0 $2 &z2 $2 ]

@div32 ( x** y** -> q** )
    ( store y and x for repeated use )
    ;div32/div1 STA2 ;div32/div0 STA2 ( y -> div )
    ;div32/rem1 STA2 ;div32/rem0 STA2 ( x -> rem )

    ( if x < y then the answer is 0 )
    ;div32/rem0 LDA2 ;div32/rem1 LDA2
    ;div32/div0 LDA2 ;div32/div1 LDA2
    ;lt32 JSR2 ,&is-zero JCN ,&not-zero JMP
    &is-zero
    #0000 #0000 RTN

    ( x >= y so the answer is >= 1 )
    &not-zero
    #0000 ;div32/quo0 STA2 #0000 ;div32/quo1 STA2 ( 0 -> quo )

    ( bitcount[x] - bitcount[y] determines the largest multiple of y to try )
    ;div32/rem0 LDA2 ;div32/rem1 LDA2 ;bitcount32 JSR2 ( rbits^ )
    ;div32/div0 LDA2 ;div32/div1 LDA2 ;bitcount32 JSR2 ( rbits^ dbits^ )
    SUB ( shift=rbits-dits )
    #00 DUP2 ( shift 0 shift 0 )

    ( 1<<shift -> cur )
    #0000 #0001 ROT2 POP
    ;left-shift JSR2 ;div32/cur1 STA2 ;div32/cur0 STA2
    
    ( div<<shift -> div )
    ;div32/div0 LDA2 ;div32/div1 LDA2 ROT2 POP
    ;left-shift JSR2 ;div32/div1 STA2 ;div32/div0 STA2 

     &loop
    ( if rem >= the current divisor, we can subtract it and add to quotient )
    ,&rem0 LDR2 ,&rem1 LDR2 ,&div0 LDR2 ,&div1 LDR2 ;lt32 JSR2 ( rem<div? )
    ,&rem-lt JCN ( if rem < div skip this iteration )

    ( if rem >= div, then we have found a multiple of y that divides x )
    ,&rem0 LDR2 ,&rem1 LDR2 ,&div0 LDR2 ,&div1 LDR2 ;sub32 JSR2 ,&rem1 STR2 ,&rem0 STR2 ( rem -= div )
    ,&quo0 LDR2 ,&quo1 LDR2 ,&cur0 LDR2 ,&cur1 LDR2 ;add32 JSR2 ,&quo1 STR2 ,&quo0 STR2 ( quo += cur )

    &rem-lt
    ,&div0 LDR2 ,&div1 LDR2 #01 ;right-shift JSR2 ,&div1 STR2 ,&div0 STR2 ( div >>= 1 )
    ,&cur0 LDR2 ,&cur1 LDR2 #01 ;right-shift JSR2 ,&cur1 STR2 ,&cur0 STR2 ( cur >>= 1 )
    ,&cur0 LDR2 ,&cur1 LDR2 ;non-zero32 JSR2 ,&loop JCN ( if cur>0, loop. else we're done )
    ,&quo0 LDR2 ,&quo1 LDR2 ( TODO: consider making this divmod32 )
    RTN
[ &div0 $2 &div1 $2
  &rem0 $2 &rem1 $2
  &quo0 $2 &quo1 $2
  &cur0 $2 &cur1 $2 ]