uxn-utils/gui/shavian/shavian.tal

|00 @System &vector $2 &expansion $2 &wst $1 &rst $1 &metadata $2 &r $2 &g $2 &b $2 &debug $1 &state $1
|10 @Console &vector $2 &read $1 &pad $4 &type $1 &write $1 &error $1
|20 @Screen &vector $2 &width $2 &height $2 &auto $1 &pad $1 &x $2 &y $2 &addr $2 &pixel $1 &sprite $1

|0000

	@id $2
	@buf $40

|0100

@on-reset ( -> )
	#f07f .System/r DEO2
	#f0d6 .System/g DEO2
	#f0b2 .System/b DEO2
	#0000 DUP2 .Screen/x DEO2
	.Screen/y DEO2
	;on-console .Console/vector DEO2
	#15 .Screen/auto DEO
	BRK

@on-console ( -> )
	.Console/read DEI
	( linebreak ) DUP #0a NEQ ?{ POP parse-line BRK }
	( append ) #00 ;buf scap/ STA2
	( #010e DEO ) BRK

@parse-line ( -- )
	;buf is-pixels ?new-pixels
	( >> )

@new-glyph ( -- )
	.id LDZ2 #0001 SUB2 <draw-glyph>
	.id LDZ2 <phex>
	#2018 DEO
	;buf <pstr>
	#0a18 DEO
	( clean ) #0000 ;buf STA2
	.id LDZ2 INC2 .id STZ2
	#0000 ;new-pixels/row STA2
	JMP2r

@new-pixels ( -- )
	#ff .id LDZ2 #40 SFT2 ;glyphs ADD2 [ LIT2 &row $2 ] INC2k ,&row STR2
	ADD2 STA
	( clean ) #0000 ;buf STA2
	JMP2r

@is-pixels ( buf* -- f )
	LDA DUP [ LIT "0 ] EQU SWP [ LIT "1 ] EQU ORA JMP2r

@<draw-glyph> ( id* -- )
	#40 SFT2 ;glyphs ADD2 .Screen/addr DEO2
	#07 .Screen/sprite DEO
	JMP2r

(
@|stdlib )

@scap ( str* -- end* )
	INC2 & LDAk ?scap
	JMP2r

@<pstr> ( str* -- )
	LDAk #18 DEO
	INC2 & LDAk ?<pstr>
	POP2 JMP2r

@<phex> ( short* -- )
	SWP <phex>/b
	&b ( -- )
		DUP #04 SFT <phex>/c
	&c ( -- )
		#0f AND DUP #09 GTH #27 MUL ADD [ LIT "0 ] ADD #18 DEO
		JMP2r

@glyphs