uxn-utils/gui/shaviankb/shaviankb.tal

( uxnemu shaviankb.rom | listener )

|00 @System &vector $2 &expansion $2 &wst $1 &rst $1 &metadata $2 &r $2 &g $2 &b $2 &debug $1 &state $1
|10 @Console &vector $2 &read $1 &pad $4 &type $1 &write $1 &error $1
|20 @Screen &vector $2 &width $2 &height $2 &auto $1 &pad $1 &x $2 &y $2 &addr $2 &pixel $1 &sprite $1
|90 @Mouse &vector $2 &x $2 &y $2 &state $1 &chord $1 &pad $4 &scrolly &scrolly-hb $1 &scrolly-lb $1

|0000

	@hover $2

|0100

@on-reset ( -> )
	#ad0f .System/r DEO2
	#ac0f .System/g DEO2
	#ab0f .System/b DEO2
	#0130 .Screen/width DEO2
	#00d0 .Screen/height DEO2
	;on-mouse .Mouse/vector DEO2
	<draw-keyboard>
	( #010e DEO ) BRK

@on-mouse ( -> )
	[ LIT2 00 -Mouse/state ] DEI NEQ #42 ADD ;pointer-icn <update-pointer>
	( | within )
	.Mouse/x DEI2 #0008 SUB2 #0120 LTH2 ?{ BRK }
	.Mouse/y DEI2 #0008 SUB2 #00c0 LTH2 ?{ BRK }
	.Mouse/state DEI ?on-mouse-down
	( | hover )
	get-mouse-key <set-hover>
	BRK

@on-mouse-down ( -> )
	BRK

(
@|core )

@get-mouse-key ( -- id* )
	( x ) .Mouse/x DEI2 #0008 SUB2 #05 SFT2
	( y ) .Mouse/y DEI2 #0008 SUB2 #0030 DIV2 #0009 MUL2 ADD2
	( last2 ) DUP #22 LTH ?{ #0004 SUB2 JMP2r }
	( space ) DUP #1d SUB #04 GTH ?{ POP2 #001d }
	JMP2r

@<set-hover> ( id* -- )
	DUP2 .hover LDZ2 EQU2 ?{
		( undraw ) .hover LDZ2 ;btn-chr <draw-key-id>
		DUP2 ;btn-hover-chr <draw-key-id>
		.hover STZ2
		( redraw ) JMP2r }
	POP2 JMP2r

@<set-position> ( id* -- )
	DUP2 #0009 DIV2 #0030 MUL2 #0008 ADD2 .Screen/y DEO2
	DUP #1e NEQ ?{ POP2 #0007 }
	DUP #1f NEQ ?{ POP2 #0008 }
	#0009 DIV2k MUL2 SUB2 #0020 MUL2 #0008 ADD2 .Screen/x DEO2
	JMP2r

(
@|drawing )

@<draw-keyboard> ( -- )
	#0020 #0000
	&l ( -- )
		DUP2 ;btn-chr <draw-key-id>
		INC2 GTH2k ?&l
	POP2 POP2 JMP2r

@<draw-key-id> ( id* frame* -- )
	OVR2 <set-position>
	OVR2 #001d EQU2 ?<draw-key-space>
	STH2
	#0006 MUL2 ;layout ADD2
	( ) STH2k #0004 ADD2 LDA2
	( ) STH2kr #0002 ADD2 LDA2
	( ) STH2r LDA2 STH2r <draw-key>
	JMP2r

@<draw-glyph> ( addr* -- )
	.Screen/addr DEO2
	[ LIT2 15 -Screen/auto ] DEO
	[ LIT2 0a -Screen/sprite ] DEO
	JMP2r

@<draw-key> ( a* b* c* frame* -- )
	DUP2 ;btn-hover-chr EQU2 STH
	<draw-button>
	.Screen/x DEI2k #0002 SUB2 ROT DEO2
	.Screen/y DEI2k #0024 STHr SUB SUB2 ROT DEO2
	( | a )
	<draw-glyph>
	.Screen/x DEI2k #0002 SUB2 ROT DEO2
	.Screen/y DEI2k #000c ADD2 ROT DEO2
	( | b )
	<draw-glyph>
	.Screen/x DEI2k #0002 SUB2 ROT DEO2
	.Screen/y DEI2k #000c ADD2 ROT DEO2
	( | c )
	<draw-glyph>
	.Screen/x DEI2k #0006 ADD2 ROT DEO2
	.Screen/y DEI2k #001c SUB2 ROT DEO2
	JMP2r

@<draw-key-space> ( id* frame* -- )
	STH2
	POP2 .Screen/x DEI2 .Screen/y DEI2 #1204 STH2r <draw-frame>
	;fill-icn .Screen/addr DEO2
	[ LIT2 31 -Screen/auto ] DEO
	#03ee !<draw-times>

@<draw-button> ( frame* -- )
	STH2
	.Screen/x DEI2 .Screen/y DEI2 #0204 STH2r <draw-frame>
	;fill-icn .Screen/addr DEO2
	[ LIT2 12 -Screen/auto ] DEO
	[ LIT2 03 -Screen/sprite ] DEOk DEOk DEOk DEO
	JMP2r

@<draw-frame> ( x* y* w h sprite* -- )
	.Screen/addr DEO2
	,&h STR
	,&w STR
	DUP2 .Screen/y DEO2
	,&y STR2
	DUP2 .Screen/x DEO2
	,&x STR2
	#01 .Screen/auto DEO
	#81 .Screen/sprite DEO
	,&next JSR [ LIT &w $1 ] ,&repeat JSR #02 .Screen/auto DEO
	,&next JSR #81 .Screen/sprite DEO
	,&next JSR [ LIT &h $1 ] ,&repeat JSR
	( left ) [ LIT2 &y $2 ] #0008 ADD2 .Screen/y DEO2
	[ LIT2 &x $2 ] .Screen/x DEO2
	,&next JSR ,&h LDR ,&repeat JSR #01 .Screen/auto DEO
	,&next JSR #81 .Screen/sprite DEO
	,&next JSR ,&w LDR ,&repeat JSR ,&next JSR #81 .Screen/sprite DEO
	( fill ) ,&next JSR ,&x LDR2 #0008 ADD2 .Screen/x DEO2
	,&y LDR2 #0008 ADD2 .Screen/y DEO2
	JMP2r
	&next .Screen/addr DEI2k #0010 ADD2 ROT DEO2
	JMP2r
	&repeat #00 &repeat-loop #81 .Screen/sprite DEO
	INC GTHk ?&repeat-loop
	POP2 JMP2r

@<draw-times> ( color times -- )
	OVR .Screen/sprite DEO
	INC DUP ?<draw-times>
	POP2 JMP2r

@<update-pointer> ( color addr* -- )
	[ LIT2 00 -Screen/auto ] DEO
	;fill-icn .Screen/addr DEO2
	#40 <draw-pointer>
	.Mouse/x DEI2 ,<draw-pointer>/x STR2
	.Mouse/y DEI2 ,<draw-pointer>/y STR2
	.Screen/addr DEO2

@<draw-pointer> ( color -- )
	[ LIT2 &x $2 ] .Screen/x DEO2
	[ LIT2 &y $2 ] .Screen/y DEO2
	.Screen/sprite DEO
	JMP2r

(
@|stdlib )

@<phex> ( short* -- )
	SWP <phex>/b
	&b ( -- )
		DUP #04 SFT <phex>/c
	&c ( -- )
		#0f AND DUP #09 GTH #27 MUL ADD [ LIT "0 ] ADD #18 DEO
		JMP2r
	
~assets.tal